|
##イベント番号及び変数及び効果音は任意です##
##コメントアウトは；で区切って行ないます##
*ev22
；丁半イベントの開始
/msg
＜片桐大地(ディーラー)＞
いらっしゃいませ。
こちらでは丁半で遊べます。
//
*ev22a
/sel
ゲーム開始,ev22b
説明を聞く,ev22c
遊ばない,ev22d
//,//
*ev22b
/f_off,86；勝ち負け判定用変数（処理抜け対策にここで一端リセットしています）
/msg
\c
＜片桐大地(ディーラー)＞
では掛け金を決めて下さい。
//
/gprint
/sel
１００円,kin1
５００円,kin2
１０００円,kin3
やっぱりやめる,ev22d
//,//
*kin1
/ifp,$g,>=,100,kin1a,kin4；所持金の判定
*kin1a
/let,#11#,100
/go,ev22ba
*kin2
/ifp,$g,>=,500,kin2a,kin4；所持金の判定
*kin2a
/let,#11#,500
/go,ev22ba
*kin3
/ifp,$g,>=,1000,kin3a,kin4；所持金の判定
*kin3a
/let,#11#,1000
/go,ev22ba
*kin4；所持金が足りない場合の処理
/msg
\c
＜片桐大地(ディーラー)＞
お金が足りないみたいですね。\n\c
//
/go,ev22b
*ev22ba
/g-,#11#
/gprint
/wav,wave\coin06.wav；コインが失われる効果音挿入（任意）
/sleep,5
/gerase
/msg
\c
＜片桐大地(ディーラー)＞
丁と半どちらに賭けますか？
//
/sel
丁,ev22bb
半,ev22bd
//
*ev22bb
/f_on,86
/go,ev22bd
*ev22bd；ゲーム画面の表示
/let,#19#,#11#
/dev,#19#,2
/inc,#19#,#11#
/mapfill,1,-1,-1
/mapmsg,10,294,"賭け金:#11#円",6,1,0,1
/mapmsg,10,310,"配当金:#19#円",6,1,0,1
/msg
\c
＜片桐大地(ディーラー)＞
では、振ります。
//
/let,#15#,0
*ev22be；ダイス回転ルーチン
/rnd,#14#,1,120
/mod,#14#,6
/fork,5,#14#,=,1,2,3,4,5,d1,d2,d3,d4,d5,d6
*ev22bf
;/sleep,1
/rnd,#14#,1,120
/mod,#14#,6
/fork,5,#14#,=,1,2,3,4,5,d1a,d2a,d3a,d4a,d5a,d6a
*ev22bg
;/sleep,1
/inc,#15#,1
/ifp,#15#,>,15,ev22bh,ev22be
*d1
/kasane,83,158,"pic\dice1.bmp","pic\dice0.bmp"
/let,#12#,1
/go,ev22bf
*d2
/kasane,83,158,"pic\dice2.bmp","pic\dice0.bmp"
/let,#12#,2
/go,ev22bf
*d3
/kasane,83,158,"pic\dice3.bmp","pic\dice0.bmp"
/let,#12#,3
/go,ev22bf
*d4
/kasane,83,158,"pic\dice4.bmp","pic\dice0.bmp"
/let,#12#,4
/go,ev22bf
*d5
/kasane,83,158,"pic\dice5.bmp","pic\dice0.bmp"
/let,#12#,5
/go,ev22bf
*d6
/kasane,83,158,"pic\dice6.bmp","pic\dice0.bmp"
/let,#12#,6
/go,ev22bf
*d1a
/kasane,193,158,"pic\dice1.bmp","pic\dice0.bmp"
/let,#13#,1
/go,ev22bg
*d2a
/kasane,193,158,"pic\dice2.bmp","pic\dice0.bmp"
/let,#13#,2
/go,ev22bg
*d3a
/kasane,193,158,"pic\dice3.bmp","pic\dice0.bmp"
/let,#13#,3
/go,ev22bg
*d4a
/kasane,193,158,"pic\dice4.bmp","pic\dice0.bmp"
/let,#13#,4
/go,ev22bg
*d5a
/kasane,193,158,"pic\dice5.bmp","pic\dice0.bmp"
/let,#13#,5
/go,ev22bg
*d6a
/kasane,193,158,"pic\dice6.bmp","pic\dice0.bmp"
/let,#13#,6
/go,ev22bg
*ev22bh；丁半判定
/let,#17#,#12#
/inc,#17#,#13#
/mod,#17#,2
/ifp,#17#,=,1,han,tyo
*tyo
/msg
\c
＜片桐大地(ディーラー)＞
#12#･#13#の丁！\n\c
//
/iff,86,dkati,dmake
*han
/msg
\c
＜片桐大地(ディーラー)＞
#12#･#13#の半！\n\c
//
/iff,86,dmake,dkati
*dkati；プレイヤー勝利時処理
/pic,//
/msg
＜片桐大地(ディーラー)＞
おめでとうございます。
アナタの勝ちです。\n\c
//
/gprint
/let,#17#,#11#
/dev,#17#,2
/inc,#17#,#11#
/msg
＜片桐大地(ディーラー)＞
こちらが払戻金の#17#円になります。\n\c
//
/g+,#17#
/gprint
/wav,wave\coin06.wav
/sleep,5
/gerase
/go,ev22bi
*dmake；プレイヤー敗北時の処理
/pic,//
/msg
＜片桐大地(ディーラー)＞
これは残念でしたね。
アナタの負けです。\n\c
//
/go,ev22bi
*ev22bi
/msg
＜片桐大地(ディーラー)＞
もう一度挑戦しますか？
//
/yesno,ev22b,ev22d
*ev22c；ルール説明
/msg
\c
＜片桐大地(ディーラー)＞
遊び方は簡単です。
最初に掛け金を決めて頂きます。\n\c
＜片桐大地(ディーラー)＞
次に丁(偶数)と半(奇数)のどちらに賭けるか
決めていただきます。\n\c
＜片桐大地(ディーラー)＞
最後に私がサイコロを振ります。
サイコロの出目が当たっていた場合は、
掛け金の１.５倍の金額をお支払いします。\n\c
＜片桐大地(ディーラー)＞
それではゲームを始めますか？
//
/yesno,ev22b,ev22d
*ev22d
/gerase
/f_off,86；勝ち負け判定用変数
/msg
\c
＜片桐大地(ディーラー)＞
またのご利用をお待ちしております。\n\c
//
/return,0
*ev23；BIG&SMALLイベントの開始
/msg
＜東雲桃香(ディーラー)＞
いらっしゃいませ。
こちらではＢＩＧ＆ＳＭＡＬＬという
ゲームを行っております。\n\c
＜東雲桃香(ディーラー)＞
特殊なルールでゲームが行われますので、
説明を一度確認して下さい。
//
*ev23a
/sel
ゲーム開始,ev23b
説明を聞く,ev23c
遊ばない,ev23d
//,//
*ev23b
/f_off,86；勝ち負け判定用変数（処理抜け対策にここで一端リセットしています）
/msg
\c
＜東雲桃香(ディーラー)＞
では掛け金を決めて下さい。
//
/gprint
/sel
５００円,gld1
１０００円,gld2
５０００円,gld3
やっぱりやめる,ev23d
//,//
*gld1
/ifp,$g,>=,500,gld1a,gld4；所持金の判定
*gld1a
/let,#11#,500
/go,ev23ba
*gld2
/ifp,$g,>=,1000,gld2a,gld4；所持金の判定
*gld2a
/let,#11#,1000
/go,ev23ba
*gld3
/ifp,$g,>=,5000,gld3a,gld4；所持金の判定
*gld3a
/let,#11#,5000
/go,ev23ba
*gld4；所持金が足りない場合の処理
/msg
\c
＜東雲桃香(ディーラー)＞
お金が足りないみたいですね。\n\c
//
/go,ev23b
*ev23ba
/g-,#11#
/gprint
/wav,wave\coin06.wav；コインが失われる効果音挿入（任意）
/sleep,5
/gerase
*ev23baa；ゲーム画面処理
/let,#19#,#11#
/mul,#19#,2
/mapfill,1,-1,-1
/mapmsg,10,294,"賭け金:#11#円",6,1,0,1
/mapmsg,10,310,"配当金:#19#円",6,1,0,1
/msg
\c
＜東雲桃香(ディーラー)＞
では、カードを出します。\n
//
/let,#12#,0
/let,#13#,0
/let,#17#,0
/let,#18#,83
/kasane,83,138,"pic\card1.bmp","pic\card0.bmp"
/kasane,193,138,"pic\card1.bmp","pic\card0.bmp"
/sleep,10
*ev23bb；カード数字決定ルーチン及びカードオープン
/rnd,#14#,1,80
/mod,#14#,20
/ifp,#12#,=,#14#,ev23bb,//
/fork,19,#14#,=,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,c1,c2,c3,c4,c5,c6,c7,c8,c9,c10,c11,c12,c13,c14,c15,c16,c17,c18,c19,c20
*c1
/kasane,#18#,138,"pic\cardb1.bmp","pic\card0.bmp"
/go,hantei
*c2
/kasane,#18#,138,"pic\cardb2.bmp","pic\card0.bmp"
/go,hantei
*c3
/kasane,#18#,138,"pic\cardb3.bmp","pic\card0.bmp"
/go,hantei
*c4
/kasane,#18#,138,"pic\cardb4.bmp","pic\card0.bmp"
/go,hantei
*c5
/kasane,#18#,138,"pic\cardb5.bmp","pic\card0.bmp"
/go,hantei
*c6
/kasane,#18#,138,"pic\cardb6.bmp","pic\card0.bmp"
/go,hantei
*c7
/kasane,#18#,138,"pic\cardb7.bmp","pic\card0.bmp"
/go,hantei
*c8
/kasane,#18#,138,"pic\cardb8.bmp","pic\card0.bmp"
/go,hantei
*c9
/kasane,#18#,138,"pic\cardb9.bmp","pic\card0.bmp"
/go,hantei
*c10
/kasane,#18#,138,"pic\cardb10.bmp","pic\card0.bmp"
/go,hantei
*c11
/kasane,#18#,138,"pic\cardr1.bmp","pic\card0.bmp"
/go,hantei
*c12
/kasane,#18#,138,"pic\cardr2.bmp","pic\card0.bmp"
/go,hantei
*c13
/kasane,#18#,138,"pic\cardr3.bmp","pic\card0.bmp"
/go,hantei
*c14
/kasane,#18#,138,"pic\cardr4.bmp","pic\card0.bmp"
/go,hantei
*c15
/kasane,#18#,138,"pic\cardr5.bmp","pic\card0.bmp"
/go,hantei
*c16
/kasane,#18#,138,"pic\cardr6.bmp","pic\card0.bmp"
/go,hantei
*c17
/kasane,#18#,138,"pic\cardr7.bmp","pic\card0.bmp"
/go,hantei
*c18
/kasane,#18#,138,"pic\cardr8.bmp","pic\card0.bmp"
/go,hantei
*c19
/kasane,#18#,138,"pic\cardr9.bmp","pic\card0.bmp"
/go,hantei
*c20
/kasane,#18#,138,"pic\cardr10.bmp","pic\card0.bmp"
/go,hantei
*hantei
/ifp,#17#,>,0,hantei2,//
/let,#17#,1
/let,#12#,#14#
/let,#18#,193
/msg
\c
＜東雲桃香(ディーラー)＞
ＢＩＧとＳＭＡＬＬどちらに賭けますか？
//
/sel
ＢＩＧ,ev23bc
ＳＭＡＬＬ,ev23bd
//
*ev23bc
/f_on,86
/go,ev23bd
*ev23bd
/msg
\c
＜東雲桃香(ディーラー)＞
わかりました。
では二枚目のカードをめくります。\n
//
/go,ev23bb；ここで右と左の判定を別に行なうのはrnd変数生成が大抵パソコンの内部時計に依存しているからです
*hantei2；二枚のカードの数を比較（以下特殊ルール導入の為、判定ルーチンが結構厄介です）
/sleep,10
/ifp,#12#,=,0,plusa,//
/ifp,#13#,=,0,plusb,hantei2a
*plusa
/let,#12#,20
/go,hantei2a
*plusb
/let,#13#,20
/go,hantei2a
*hantei2a
/let,#13#,#14#
/let,#15#,#12#
/let,#16#,#13#
/ifp,#15#,>,10,jyo1,//
/ifp,#16#,>,10,jyo2,nao
*jyo1
/dec,#15#,10
/ifp,#16#,>,10,jyo2,nao
*jyo2
/dec,#16#,10
/go,nao
*nao
/ifp,#15#,=,#16#,eq,//
/ifp,#15#,=,10,nao1,//
/ifp,#16#,=,10,nao2,hantei3
*nao1
/ifp,#16#,=,1,big,small
*nao2
/ifp,#15#,=,1,small,big
*hantei3
/ifp,#15#,<,#16#,big,small
*eq
/ifp,#12#,>,#13#,big,small；ここまでが判定ルーチンになります
*small
/msg
\c
＜東雲桃香(ディーラー)＞
ＳＭＡＬＬです。\n\c
//
/iff,86,cmake,ckati
*big
/msg
\c
＜東雲桃香(ディーラー)＞
ＢＩＧです。\n\c
//
/iff,86,ckati,cmake
*ckati
/pic,//
/msg
＜東雲桃香(ディーラー)＞
おめでとうございます。
アナタの勝ちです。\n\c
//
/f_off,86
/mul,#11#,2
/go,ev23bi
*cmake
/pic,//
/msg
＜東雲桃香(ディーラー)＞
これは残念でしたね。
アナタの負けです。\n\c
//
/go,ev23bj
*ev23bi
/msg
＜東雲桃香(ディーラー)＞
もう一度挑戦しますか？
//
/yesno,ev23baa,ev23bia
*ev23bia
/gprint
/msg
\c
＜東雲桃香(ディーラー)＞
では、こちらが払戻金の#11#円になります。\n\c
//
/g+,#11#
/gprint
/wav,wave\coin06.wav
/sleep,5
/gerase
/go,ev23d
*ev23bj
/msg
＜東雲桃香(ディーラー)＞
もう一度挑戦しますか？
//
/yesno,ev23b,ev23d
*ev23c；ルール説明
/msg
\c
＜東雲桃香(ディーラー)＞
それでは説明させて頂きます。\n\c
＜東雲桃香(ディーラー)＞
最初に掛け金を決めて頂きます。
掛け金が決まりましたら、私が場にカードを
二枚伏せて出します。\n\c
＜東雲桃香(ディーラー)＞
左側のカードをめくりますので、右側のカードが
それよりも大きいか小さいかを決めて下さい。\n\c
＜東雲桃香(ディーラー)＞
カードの枚数は二十枚。
内訳はスペード及びハートの１〜１０までです。\n\c
＜東雲桃香(ディーラー)＞
このゲームにはドロップやドロウはありません。
必ず勝敗が決定するように以下の特別ルールが
採用されています。\n\c
＜東雲桃香(ディーラー)＞
１０が最大の数になりますが、これに対して
１が出た場合は１の方が大きいと判断します。
１に対して１０が出た場合は、１０の方が
小さいと判断します。\n\c
＜東雲桃香(ディーラー)＞
同じ数が出てしまった場合はスペードの方が
大きいと判断します。\n\c
＜東雲桃香(ディーラー)＞
プレイヤーが勝ち、ゲーム続行を選択した場合は
ダブルアップになります。
配当金をそのまま全額賭けて次の勝負に望みます。\n\c
＜東雲桃香(ディーラー)＞
勝てば更に倍になりますが、負けた場合は当然、
前回の配当金も貰えません。
ダブルアップに回数制限はありません。\n\c
＜東雲桃香(ディーラー)＞
配当金は掛け金の２倍になります。
ゲームを始めますか？
//
/yesno,ev23b,ev23d
*ev23d
/gerase
/f_off,86；勝ち負け判定用フラグ
/msg
\c
＜東雲桃香(ディーラー)＞
またのご利用をお待ちしております。\n\c
//
/return,0 |
